• 首页
• HFSS教程
• ADS教程
• CST教程
• 射频工程师培训
• 微波仪器操作培训
• 天线设计培训
• 射频专业基础课

Ansoft Designer / Ansys Designer 在线帮助文档：

Nexxim Simulator >
Nexxim Component Models >
Resistors >
   Resistor, Ideal Tuner (Netlist Only)       

Resistor, Ideal Tuner (Netlist Only)

.

Netlist Format

The ideal tuner defines a port for Load-Pull Analysis. The ideal tuner syntax is based on the Resistor device:

Rxxxx n1 n2 PORTNUM=val
[GAMMA_REAL=val GAMMA_IMAG=val]
GAMMA_MAG=val GAMMA_ANG=val
[REF_REAL=val] [REF_IMAG=val]
[TUNER_FREQS=[val [, val...]]]
[Z_FREQS=[val [, val...]]]
[Z_REAL=[val [, val...]]]
[Z_IMAG=[val [, val...]]]
[RDEF=val] [XDEF=val]
[RDC=val]

n1 is the positive node and n2 is the negative node of the tuner. The current is assumed to flow from n1 through the tuner to n2.

The reflection coefficient gamma (G) can be specified using EITHER the GAMMA_REAL/GAMMA_IMAG parameters OR the GAMMA_MAG/GAMMA_ANG parameters, but not both. Typically, the GAMMA_MAG/GAMMA_ANG parameters are used.

In the syntax above, the bold brackets [ ] are required when the list of values contains more than one element.

Ideal Tuner Netlist Example

The netlist sets up a load-pull analysis by defining netlist parameters ZRho (sample impedance) and ZAng (angle of sample impedance), using these netlist parameters to set an ideal tuner element, and setting up sweeps of the ZRho and ZAng parameters as part of the HB analysis statement. The bolded lines in the example netlist below show the additions for the load-pull analysis, including the ideal tuner element.

* Nexxim Load-Pull Netlist Example

.PARAM Freq1=1.5e9
.PARAM Freq2=2.2e9

.PARAM ZRho=1 // Sample impedance for load-pull
.PARAM ZAng=0 // Sample impedance angle

V1 net_0 0 DC=0.5 SIN(0 0.5 Freq1 0 0 0)
V2 net_0 0 DC=0.5 SIN(0 0.5 Freq2 0 0 0)
R2 net_0 Port1 1000

RPort1 Port1 0 PORTNUM=1 // Ideal tuner element
+ GAMMA_MAG=ZRho GAMMA_ANG=ZAng // Reflection coefficient
+ REF_REAL=50 REF_IMAG=0 // Reference impedance
+ TUNER_FREQS=[Freq1, Freq2] // Main tuner frequencies
+ Z_FREQS=['2*Freq1-Freq2', '2*Freq2-Freq1'] // Cluster freqs
+ Z_REAL=[100, 100] Z_IMAG=[0.5, 0.5] // Cluster impedances
+ RDC=50 // Tuner Resistance at DC
+ RDEF=50 XDEF=0 // Default tuner impedance for all frequencies

.HB
+ TONES=[Freq1, Freq2] MAXK=[2, 2]
+ SWEEP // Sweeps of ZRho and ZAng implement the load-pull
+ ZRho LIN 11 0 1
+ ZAng LIN 13 0 6.283185307
.END

Notes

1. The ideal tuner resistor is required in a netlist-based design only for Load-Pull Analysis, where it is necessary to use a port with a variable reflection coefficient. For schematic designs created within Designer, the load-pull analysis setup creates an ideal tuner automatically on the selected schematic port. For this reason, no Ideal Tuner element is available in the Schematic Editor interface.

2. At the frequencies specified by the TUNER_FREQS list, Nexxim load-pull analysis computes the input impedance Z of an ideal tuner from the following formula:

Where G is the reflection coefficient and Z_r is the reference impedance of the tuner. The tuner instance parameters define Γ and Z_r. The impedance calculation is performed over a combined sweep of GAMMA_MAG and GAMMA_ANG. GAMMA_MAG is typically swept over a range from zero to one, and GAMMA_ANG is swept over a range of zero to 2p (6.283185307) radians. At each sweep point, a harmonic balance is performed to solve for the circuit responses at the calculated tuner impedance.

3. At the frequencies specified in the Z_FREQS list, the impedance is taken from the corresponding Z_REAL and Z_IMAG lists.

4. When no tuner frequency or cluster freqeuency matches the current HB frequency, the default impedance given by RDEF and XDEF is used.

5. The DC resistance is given by RDC for time-domain analyses.

                HFSS视频教程                                      ADS视频教程                               CST视频教程                           Ansoft Designer 中文教程

      Copyright © 2006 - 2013   微波EDA网, All Rights Reserved    业务联系：mweda@163.com