• 首页
• HFSS教程
• ADS教程
• CST教程
• 射频工程师培训
• 微波仪器操作培训
• 天线设计培训
• 射频专业基础课

Ansoft Designer / Ansys Designer 在线帮助文档：

Designer File Formats >
   Nexxim Netlist Format >
       Netlist File Structure >
           Statements >
               ALTER Statements                   

ALTER Statements

The ALTER statement directs Nexxim to resimulate a netlist using changed values for parameters. The netlist may contain any number of ALTER statements.

The syntax is:

$ Rest of netlist
.ALTER [title1]
$ ALTER block statements

[.ALTER title2
$ ALTER block statements]

...

.END

The ALTER statements should come after all other statements in the netlist except for the END statement. An ALTER block can contain the following kinds of statements:

• .DEL LIB

• .INCLUDE

• .IC

• .LIB

• .MODEL

• .NODESET

• .OPTIONS

• .PARAM

• .PRINT

• .SUBCKT .. .ENDS

• .TEMP

• Analysis statements (see Analysis Controls for a list)

• Device instances, including subcircuits.

In the ALTER block, you can assign a new value to any device instance name, model name, netlist parameter name, or option name from the main netlist. You can also define new device instances, models, subcircuits, netlist parameters, and options. In the simplest case, the netlist contains just one ALTER statement. Nexxim first simulates the netlist from the beginning up to the first ALTER statement. Nexxim then reanalyzes the netlist, using any changes made in the ALTER statement, up to the END statement. The simulation includes the analyses specified in the original netlist, plus any analyses added in the ALTER block. All the analyses use the values of parameters, etc. set in the ALTER block.

When more than one ALTER block is present, Nexxim first simulates the netlist from the beginning up to the first ALTER statement, as before. Nexxim then reanalyzes the netlist, using any changes made in the first ALTER block, up to the second ALTER statement. The simulation includes the analyses specified in the original netlist, plus any analyses added in the first ALTER block. All the analyses use the values of parameters, etc. set in the first ALTER block.

Nexxim next re-analyzes the netlist, using any changes made in the second ALTER block, up to the next ALTER statement (or up to the END statement, if there are just two ALTER blocks). The simulation includes the analyses specified in the original netlist, plus any analyses added in the first ALTER block, plus any analyses added in the second ALTER block. All the analyses use the values of parameters, etc. set in the second ALTER block.

Nexxim continues resimulating the circuit until the last ALTER statement has been processed. Following is an example:

* Test of ALTER blocks

.param myval=1000

V1 1 0 sin(0 1 myval)
R1 1 2 1000
C1 1 2 0.001
R2 2 0 1000

.TRAN 1e-6 2e-3
.PRINT TRAN V(2)

.ALTER first_one
.param myval=2000
.HB TONES=2000 MAXk=3
.PRINT HB V(2)

.ALTER second_one
.param myval=3000
.LNA POI 3 1000 3000
.PRINT LNA V(2)

.END

For this example, Nexxim would first run a transient analysis with netlist parameter myval equal to 1000. After reading ALTER block first_one, Nexxim would then run a transient analysis and a harmonic balance analysis, both with myval equal to 2000. Finally, after reading ALTER block second_one, Nexxim would run a transient analysis, a harmonic balance analysis, and a linear network analysis, all with myval equal to 3000.

The .DEL LIB and LIB statements allow an ALTER block to control which library files are active for each variation on the netlist. Using these statements, you can avoid rerunning any previous analyses and only run the analyses specified within specific ALTER blocks. Put all the affected simulation commands into a library file referenced with a LIB statement, either in the outer netlist or in an ALTER block. Then an ALTER block uses DEL LIB to delete the unwanted statements.

Suppose the library file analyses.lib contains the following blocks:

*analyses.lib
.LIB T1
.TRAN 1e-6 2e-3
.PRINT TRAN V(2)
.ENDL
.LIB H1
.HB TONES=2000 MAXk=3
.PRINT HB V(2)
.ENDL
.LIB L1
.LNA POI 3 1000 3000
.PRINT LNA V(2)
.ENDL

The netlist from the previous example could be modified as follows:

* Test of ALTER blocks with Library file

.param myval=1000

V1 1 0 sin(0 1 myval)
R1 1 2 1000
C1 1 2 0.001
R2 2 0 1000

.LIB 'analyses.lib' T1

.ALTER first_one
.param myval=2000
.DEL LIB 'analyses.lib' T1
.LIB 'analyses.lib' H1

.ALTER second_one
.param myval=3000
.DEL LIB 'analyses.lib' H1
.LIB 'analyses.lib' L1

.END

With this netlist, Nexxim first runs the transient analysis specified in the library block T1, using netlist parameter myval equal to 1000. Next, after reading ALTER block first_one, Nexxim deletes the transient analysis library block T1 and executes the harmonic balance analysis specified in library block H1, using netlist parameter myval equal to 2000. Last, after reading ALTER block second_one, Nexxim deletes the harmonic balance analysis library block H1 and executes the linear network analysis specified in library block L1, using netlist parameter myval equal to 3000.

                HFSS视频教程                                      ADS视频教程                               CST视频教程                           Ansoft Designer 中文教程

      Copyright © 2006 - 2013   微波EDA网, All Rights Reserved    业务联系：mweda@163.com